# Switch

Eingänge register

Switch

OFF

Switch ver: 1

# Ausgänge

ID	Kürzel	Name	Typ	Standard
`click`	`C`	click	BOOLEAN	`false`
`short_press`	`SP`	short_press	BOOLEAN	`false`
`long_press`	`LP`	long_press	BOOLEAN	`false`
`hold`	`H`	hold	BOOLEAN	`false`
`toggle`	`TG`	toggle	BOOLEAN	`false`
`on`	`ON`	on	BOOLEAN	`false`
`off`	`OFF`	off	BOOLEAN	`true`

# Konfiguration

ID	Name	Typ	Standard	Einheit	Beschreibung
`click_duration_ms`	click_duration_ms	NUMBER	`500`	ms	Details: ≥ 0
`short_press_duration_ms`	short_press_duration_ms	NUMBER	`1000`	ms	Details: ≥ 0 > `click_duration_ms`
`long_press_duration_ms`	long_press_duration_ms	NUMBER	`5000`	ms	Details: ≥ 0 > `short_press_duration_ms`
`hold_duration_ms`	hold_duration_ms	NUMBER	`1000`	ms	Details: ≥ 0

# Zustand

ID	Name	Typ	Standard	Einheit	Beschreibung
`last_change_time_ms`	last_change_time_ms	NUMBER	`0`	ms

# Quellcode

Volang-Quellcode anzeigen

callback_ms = 100
channel = input::channel()

extern fn onCallback(callback_id, callback_ms) {
    if (callback_id == 1) {
        output::set("click", false)
    } else if (callback_id == 2) {
        output::set("short_press", false)
    } else if (callback_id == 3) {
        output::set("long_press", false)
    } else if (callback_id == 10) { // hold check
        if (output::get("on") == true) {
            if (output::get("hold")) {
                output::set("hold", false)
                callback::set(config::get("hold_duration_ms"), "onCallback", 10, callback_ms)
            } else if (!output::get("hold")) {
                output::set("hold", true)
                callback::set(callback_ms, "onCallback", 10, callback_ms) // schedule callback to switch off the hold pulse
            }
        }
    }
}

pressed = input::value()
now = time::uptime()

if (pressed == 1) {
    state::set("last_change_time_ms", now)
    output::set("on", true)
    output::set("off", false)

    callback::set(config::get("hold_duration_ms"), "onCallback", 10, callback_ms)
} else {
    callback::clear()

    diff_ms = time::uptime() - state::get("last_change_time_ms")

    clicked = false
    if (diff_ms <= config::get("click_duration_ms")) {
        output::set("click", true)
        callback::set(callback_ms, "onCallback", 1, callback_ms)
        clicked = true
    } else if (diff_ms <= config::get("short_press_duration_ms")) {
        output::set("short_press", true)
        callback::set(callback_ms, "onCallback", 2, callback_ms)
    } else if (diff_ms <= config::get("long_press_duration_ms")) {
        output::set("long_press", true)
        callback::set(callback_ms, "onCallback", 3, callback_ms)
    }

    if (clicked) {
        output::toggle("toggle")
    }
    output::set("on", false)
    output::set("off", true)

    output::set("hold", false)
}