# Numeric throttle

Verarbeitung

Numeric throttle

Numeric throttle ver: 1

# Eingänge

ID	Kürzel	Name	Typ	Standard	Beschreibung
`value`	`V`	value	NUMBER	`0`

# Ausgänge

ID	Kürzel	Name	Typ	Standard	Beschreibung
`value`	`V`	value	NUMBER	`0`

# Konfiguration

ID	Name	Typ	Standard	Einheit	Beschreibung
`min_change`	min_change	NUMBER	`0`		Details: ≥ 0
`discard_period`	discard_period	NUMBER	`0`	s	Details: ≥ 0

# Zustand

ID	Name	Typ	Standard	Einheit	Beschreibung
`discarding`	discarding	BOOLEAN	`false`

# Quellcode

Volang-Quellcode anzeigen

channel = input::channel()
value = input::value()

extern fn onCallback(v) {
    state::set("discarding", false)

    min_change = config::get("min_change")
    discard_ms = math::round(config::get("discard_period") * 1000)
    current_input = input::get("value")
    current_output = output::get("value")

    diff = math::abs(current_input - current_output)
    if (diff > 0 and diff >= min_change) {
        output::set("value", current_input)

        if (discard_ms > 0) {
            state::set("discarding", true)
            callback::set(discard_ms, "onCallback", 0)
        }
    }
}

if (channel == "value") {
    discarding = state::get("discarding")
    if (discarding) {
        return
    }

    min_change = config::get("min_change")
    discard_ms = math::round(config::get("discard_period") * 1000)
    current_output = output::get("value")

    diff = math::abs(value - current_output)
    if (diff >= min_change) {
        output::set("value", value)

        if (discard_ms > 0) {
            state::set("discarding", true)
            callback::clear()
            callback::set(discard_ms, "onCallback", 0)
        }
    }
}